(define-attributes ("default"))
(define-location-class "page-numbers" ("arabic-numbers"))
(markup-index :open  "~n\begin{theindex}~n
  \providecommand*\lettergroupDefault[1]{\textbf{Symbole}}
     \providecommand*\lettergroup[1]{%
         \par\textbf{#1}\par
          \nopagebreak}"
              :close "~n\end{theindex}~n"
              :tree)
(markup-letter-group :open-head "~n  \lettergroupDefault{" :close-head "}"
                     :group "default")
(markup-letter-group :open-head "~n~n  \textbf{" :close-head "}~n"
                     :capitalize)
(markup-locclass-list :open "\dotfill{}")
(markup-locref-list   :sep ", ")
(markup-range :sep "--")
(markup-indexentry :open "~n  \item "           :depth 0)
(markup-indexentry :open "~n     \subitem "     :depth 1)
(define-letter-group "A--D" :prefixes ("A" "B" "C" "D") )
(define-letter-group "E--G" :after "A--D" :prefixes ("E" "F" "G") )
(define-letter-group "H--K" :after "E--G" :prefixes ("H" "I" "J" "K"))
(define-letter-group "L--N" :after "H--K" :prefixes ("L" "M" "N"        ))
(define-letter-group "O--R" :after "L--N" :prefixes ("O" "P" "Q" "R"))
(define-letter-group "S--V" :after "O--R" :prefixes ("S" "T" "U" "V"))
(define-letter-group "W--Z" :after "S--V" :prefixes ("W" "X" "Y" "Z"))
(define-letter-group "Zahlen"  :before "A--D"
:prefixes ("0" "1" "2" "3" "4" "5" "6" "7" "8" "9") )
(merge-rule "[0-9][0-9][0-9][0-9][0-9][0-9]" "0&" :eregexp)
(merge-rule "[0-9][0-9][0-9][0-9][0-9]" "00&" :eregexp)
(merge-rule "[0-9][0-9][0-9][0-9]" "000&" :eregexp)
(merge-rule "[0-9][0-9][0-9]" "0000&" :eregexp)
(merge-rule "[0-9][0-9]" "00000&" :eregexp)
(merge-rule "[0-9]" "000000&" :eregexp)
(sort-rule "a" "A")
(sort-rule "b" "B")
(sort-rule "c" "C")
(sort-rule "d" "D")
(sort-rule "e" "E")
(sort-rule "f" "F")
(sort-rule "g" "G")
(sort-rule "h" "H")
(sort-rule "i" "I")
(sort-rule "j" "J")
(sort-rule "k" "K")
(sort-rule "l" "L")
(sort-rule "m" "M")
(sort-rule "n" "N")
(sort-rule "o" "O")
(sort-rule "p" "P")
(sort-rule "q" "Q")
(sort-rule "r" "R")
(sort-rule "s" "S")
(sort-rule "t" "T")
(sort-rule "u" "U")
(sort-rule "v" "V")
(sort-rule "w" "W")
(sort-rule "x" "X")
(sort-rule "y" "Y")
(sort-rule "z" "Z")
(markup-letter-group-list :sep "~n\indexspace")
(sort-rule "Ö" "O")
(sort-rule "ö" "o")
(merge-rule "mit" "Mit")
(merge-rule "\\[a-zA-Z@]+ *" "" :eregexp)
(merge-rule "\\[^a-zA-Z@]" "" :eregexp)
(merge-rule "^[{}$]" "" :eregexp)
