gain
Prev | Orchestra Opcodes and Operators | Next

## gain

gain — Adjusts the amplitude audio signal according to a root-mean-square value.

## Description

Adjusts the amplitude audio signal according to a root-mean-square value.

## Syntax

    ares gain asig, krms [, ihp] [, iskip]

## Initialization

ihp (optional, default=10) -- half-power point (in Hz) of a special internal low-pass filter. The default value is 10.

iskip (optional, default=0) -- initial disposition of internal data space (see reson). The default value is 0.

## Performance

asig -- input audio signal

gain provides an amplitude modification of asig so that the output ares has rms power equal to krms. rms and gain used together (and given matching ihp values) will provide the same effect as balance.

## Examples

Here is an example of the gain opcode. It uses the file gain.csd.

Example 380. Example of the gain opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o gain.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

      asrc buzz  .8, 440, sr/440, 1    ; band-limited pulse train.
      a1   reson asrc, 1000, 100       ; Sent through
      a2   reson a1, 3000, 500         ; 2 filters
      krms rms   asrc                  ; then balanced
      afin gain  a2, krms              ; with source
           outs  afin, afin
    endin

    </CsInstruments>
    <CsScore>
    ;sine wave.
    f 1 0 16384 10 1

    i 1 0 2
    e
    </CsScore>
    </CsoundSynthesizer>

## See Also

balance, rms

Prev | Up | Next
ftsr | Home | gainslider