lpreson
Prev | Orchestra Opcodes and Operators | Next

## lpreson

lpreson — Resynthesises a signal from the data passed internally by a previous lpread.

## Description

Resynthesises a signal from the data passed internally by a previous lpread.

## Syntax

    ares lpreson asig

## Performance

asig -- an audio driving function for resynthesis.

lpreson receives values internally produced by a leading lpread.lpread gets its values from the control file according to the input value ktimpnt (in seconds). If ktimpnt proceeds at the analysis rate, time-normal synthesis will result; proceeding at a faster, slower, or variable rate will result in time-warped synthesis. At each k-period, lpread interpolates between adjacent frames to more accurately determine the parameter values (presented as output) and the filter coefficient settings (passed internally to a subsequent lpreson).

The error signal kerr (between 0 and 1) derived during predictive analysis reflects the deterministic/random nature of the analyzed source. This will emerge low for pitched (periodic) material and higher for noisy material. The transition from voiced to unvoiced speech, for example, produces an error signal value of about .3. During synthesis, the error signal value can be used to determine the nature of the lpreson driving function: for example, by arbitrating between pitched and non-pitched input, or even by determining a mix of the two. In normal speech resynthesis, the pitched input to lpreson is a wideband periodic signal or pulse train derived from a unit such as buzz, and the nonpitched source is usually derived from rand. However, any audio signal can be used as the driving function, the only assumption of the analysis being that it has a flat response.

lpfreson is a formant shifted lpreson, in which kfrqratio is the (cps) ratio of shifted to original formant positions. This permits synthesis in which the source object changes its apparent acoustic size. lpfreson with kfrqratio = 1 is equivalent to lpreson.

Generally, lpreson provides a means whereby the time-varying content and spectral shaping of a composite audio signal can be controlled by the dynamic spectral content of another. There can be any number of lpread/lpreson (or lpfreson) pairs in an instrument or in an orchestra; they can read from the same or different control files independently.

## Examples

Here is an example of the lpreson opcode. It uses the file lpreson.csd.

Example 520. Example of the lpreson opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o lpreson.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1
    ; works with or without -a option when analyzing "fox.wav" from the manual
    ;both options sound a little different
    instr 1

    ilen  filelen "fox.wav"	; length of soundfile
    prints "fox.wav = %f seconds\\n",ilen

    ktime line 0, p3, p4
    krmsr,krmso,kerr,kcps lpread ktime,"fox_poles.lpc"

    krmso = krmso*.00001			; low volume
    asig  buzz krmso, kcps, int(sr/2/kcps), 1 ; max harmonics without aliasing
    aout  lpreson asig
    asig  clip aout, 0, 1			; prevents distortion
          outs asig, asig

    endin
    </CsInstruments>
    <CsScore>
    ; sine
    f1 0 4096 10 1

    i 1 0 2.8 1	; first words only
    i 1 4 2.8 2.8	; whole sentence
    e
    </CsScore>
    </CsoundSynthesizer>

The audio file “fox.wav” is 2.8 seconds long. So filelen's output should be a line like this:

    fox.wav = 2.756667 seconds

Here is another example of the lpreson opcode. It uses the file lpreson-2.csd.

Example 521. Another example of the lpreson opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o lpreson-2.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1
    ; works with or without -a option when analyzing "fox.wav" from the manual
    ;both options sound a little different
    instr 1

    ilen   filelen "fox.wav"	;length of soundfile 1
    prints "fox.wav = %f seconds\\n",ilen

    ktime  line 0, p3, ilen
    krmsr,krmso,kerr,kcps lpread ktime,"fox_nopoles.lpc"
    asig   diskin2	"flute.aiff", 1
    aout   lpreson asig
    ares   balance aout, asig
           outs ares, ares

    endin
    </CsInstruments>
    <CsScore>

    i 1 0 2.8
    e
    </CsScore>
    </CsoundSynthesizer>

## See Also

lpfreson, lpread

Prev | Up | Next
lpread | Home | lpshold