STKWurley
Prev | Orchestra Opcodes and Operators | Next

## STKWurley

STKWurley — STKWurley simulates a Wurlitzer electric piano FM synthesis instrument.

## Description

STKWurley simulates a Wurlitzer electric piano FM synthesis instrument. It uses two simple FM Pairs summed together, also referred to as algorithm 5 of the TX81Z.

## Syntax

    asignal STKWurley ifrequency, iamplitude, [kc1, kv1[, kc2, kv2[, kc3, kv3[, kc4, kv4[, kc5, kv5]]]]]

## Initialization

ifrequency -- Frequency of note played, in Hertz.

iamplitude -- Amplitude of note played (range 0-1).

## Performance

kc1, kv1, kc2, kv2, kc3, kv3, kc4, kv4, kc5, kv5, kc6, kv6, kc7, kv7, kc8, kv8 -- Up to 8 optional k-rate controller pairs for the STK opcodes. Each controller pair consists of a controller number (kc) followed by a controller value (kv). The 5 controller numbers and values that work for STKWurley are:

- kc, kv -- 2, modulator index 1.

- kc, kv -- 4, crossfade of outputs.

- kc, kv -- 11, speed of low-frequency oscillator.

- kc, kv -- 1, depth of low-frequency oscillator.

- kc, kv -- 128, ADSR 2 and 4 target.

| Note
The code for this opcode is taken directly from the Wurley class in the Synthesis Toolkit in C++ by Perry R. Cook and Gary P. Scavone. More on the STK classes can be found here: https://ccrma.stanford.edu/software/stk/classes.html

## Examples

Here is an example of the STKWurley opcode. It uses the file STKWurley.csd.

Example 824. Example of the STKWurley opcode.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;RT audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o STKWurley.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

    instr 1

    ifrq	=	p4
    kndx	line	p5, p3, p6				;(FM) Modulator Index One
    kspd	=	p7

    asig	STKWurley cpspch(p4), 1, 2,kndx, 4, 10, 11, kspd, 1, 30, 128, 75
    	outs asig, asig
    endin

    </CsInstruments>
    <CsScore>

    i 1 0 .5 7.00 75  0  20
    i 1 + .  8.00 120 0  20
    i 1 + 1  6.00 50 120 20
    i 1 + 4  8.00 10 10  127
    e
    </CsScore>
    </CsoundSynthesizer>

## See Also

STKRhodey.

## Credits

Author: Michael Gogins (after Perry Cook)
Irreducible Productions
New York, NY

New in Csound version 5.11

Prev | Up | Next
STKWhistle | Home | strchar