STKBlowBotl
Prev | Orchestra Opcodes and Operators | Next

## STKBlowBotl

STKBlowBotl — STKBlowBotl uses a helmholtz resonator (biquad filter) with a polynomial jet excitation.

## Description

This opcode implements a helmholtz resonator (biquad filter) with a polynomial jet excitation (a la Cook).

## Syntax

    asignal STKBlowBotl ifrequency, iamplitude, [kc1, kv1[, kc2, kv2[, kc3, kv3[, kc4, kv4]]]]

## Initialization

ifrequency -- Frequency of note played, in Hertz.

iamplitude -- Amplitude of note played (range 0-1).

## Performance

kc1, kv1, kc2, kv2, kc3, kv3, kc4, kv4, kc5, kv5, kc6, kv6, kc7, kv7, kc8, kv8 -- Up to 8 optional k-rate controller pairs for the STK opcodes. Each controller pair consists of a controller number (kc) followed by a controller value (kv). The 4 controller numbers and values that work for STKBlowBotl are:

- kc, kv -- 4, gain of noise.

- kc, kv -- 11, speed of low-frequency oscillator.

- kc, kv -- 1, depth of low-frequency oscillator.

- kc, kv -- 128, volume

| Note
The code for this opcode is taken directly from the BlowBotl class in the Synthesis Toolkit in C++ by Perry R. Cook and Gary P. Scavone. More on the STK classes can be found here: https://ccrma.stanford.edu/software/stk/classes.html

## Examples

Here is an example of the STKBlowBotl opcode. It uses the file STKBlowBotl.csd.

Example 800. Example of the STKBlowBotl opcode.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;RT audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o STKBlowBotl.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

    instr 1

    ipch	= p4
    knoise	line p5, p3, p6					;noise
    kvol	line	100, p3, 70				;volume

    asig	STKBlowBotl cpspch(ipch), 1, 4, knoise, 11, 10, 1, 50, 128, kvol
    asig	=	asig * .7				;too loud
    	outs	asig, asig
    endin

    </CsInstruments>
    <CsScore>

    i 1 0 2 9.00 20 100
    i 1 + 3 8.03 120 0
    e
    </CsScore>
    </CsoundSynthesizer>

## Credits

Author: Michael Gogins (after Perry Cook)
Irreducible Productions
New York, NY

New in Csound version 5.11

Prev | Up | Next
STKBeeThree | Home | STKBlowHole