Test::Stream::Event(3)

NAME
Test::Stream::Event - Base class for events

DEPRECATED
This distribution is deprecated in favor of Test2, Test2::Suite, and Test2::Workflow.

See Test::Stream::Manual::ToTest2 for a conversion guide.

DESCRIPTION
Base class for all event objects that get passed through Test::Stream.

SYNOPSIS
    package Test::Stream::Event::MyEvent;
    use strict;
    use warnings;

    # This will make our class an event subclass (required)
    use base 'Test::Stream::Event';

    # Add some accessors
    use Test::Stream::HashBase accessors => [qw/foo bar baz/];

    # Chance to initialize some defaults
    sub init {
        my $self = shift;
        # no other args in @_

        $self->SUPER::init();

        $self->set_foo('xxx') unless defined $self->foo;

        # Events are arrayrefs, all accessors have a constant defined with
        # their index.
        $self->[BAR] ||= "";

        ...
    }

    1;

METHODS

$dbg = $e->debug
    Get a snapshot of the debug info as it was when this event was generated

$bool = $e->causes_fail
    Returns true if this event should result in a test failure. In general this should be false.

$call = $e->created
    Get the caller() details from when the event was generated. This is usually inside a tools package. This is typically used for debugging.

$num = $e->nested
    If this event is nested inside of other events, this should be the depth of nesting. (This is mainly for subtests)

$e->update_state($state)
    This callback is used by Test::Stream::Hub to give your event a chance to update the state.

    This is called BEFORE your event is passed to the formatter.

$bool = $e->global
    Set this to true if your event is global, that is ALL threads and processes should see it no matter when or where it is generated. This is not a common thing to want, it is used by bail-out and skip_all to end testing.

$code = $e->terminate
    This is called AFTER your event has been passed to the formatter. This should normally return undef, only change this if your event should cause the test to exit immedietly.

    If you want this event to cause the test to exit you should return the exit code here. Exit code of 0 means exit success, any other integer means exit with failure.

    This is used by Test::Stream::Event::Plan to exit 0 when the plan is 'skip_all'. This is also used by Test::Stream::Event:Bail to force the test to exit with a failure.

    This is called after the event has been sent to the formatter in order to ensure the event is seen and understood.

@output = $e->to_tap($num)
    This is where you get the chance to produce TAP output. The input argument $num will either be the most recent test number, or undefined. The output should be a list of arrayrefs, each arrayref should have exactly 2 values: "$HID, $TEXT". The HID tells the formatter which output handle to use (see the constants provided by Test::Stream::Formatter::TAP), $TEXT should be the text that is output to the specified handle.

    Example:

        package Test::Stream::Event::MyEvent;
        use base 'Test::Stream::Event';
        use Test::Stream::Formatter::TAP qw/OUT_STD OUT_TODO OUT_ERR/;

        sub to_tap {
            my $self = shift;
            my ($num) = @_;

            # Using test numbers
            if (defined $num) {
                return (
                    [OUT_STD, "# Got MyEvent!"],
                    [OUT_ERR, "# The last test was $num"],
                );
            }

            # Not using test numbers.
            return (
                [OUT_STD, "# Got MyEvent!"],
            );
        }

SOURCE
The source code repository for Test::Stream can be found at http://github.com/Test-More/Test-Stream/.

MAINTAINERS

Chad Granum <exodist@cpan.org>

AUTHORS

Chad Granum <exodist@cpan.org>

COPYRIGHT
Copyright 2015 Chad Granum <exodist7@gmail.com>.

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

See http://dev.perl.org/licenses/